Unityでスクリプトからシェーダのキーワード定義を変更して処理を切り替える その２（複数のシェーダのキーワードを組み合わせる）

本日はUnityの小ネタ枠です。
Unityでスクリプトからシェーダのキーワード定義を変更して処理を切り替える方法です。
今回は複数のシェーダのキーワードを組み合わせるケースについてです。

複数のキーワードを組み合わせる

複数の multi_compile の定義を行うと、それらの全ての組み合わせパターンのシェーダファイル(バリアント)が作られます。
docs.unity3d.com

# pragma multi_compile A B C
# pragma multi_compile D E

上記の定義を行った場合、合計 6 のシェーダーバリアント（ A + D、B + D、C + D、A + E、B + E、C + E ）が生成されます。
これにより A B C と D E のキーワードの組み合わせでシェーダの動作を変更できます。

# pragma multi_compile A B C D E

上記の定義を行った場合、合計 5 のシェーダーバリアント（ A、B、C、D、E ）が生成されます。
この場合、キーワードの組み合わせは利用できません。

前回記事

以下の記事で作成したサンプルシェーダとスクリプトを基にサンプルを作成します。
bluebirdofoz.hatenablog.com

サンプルシーン

前回記事で作成したサンプルスクリプトに複数のキーワードを組み合わせて有効にするメソッドを追加しました。
・ShaderController.cs

using UnityEngine;

public class ShaderController : MonoBehaviour
{
    private readonly string _shaderKeywordRed = "FORCE_RED_COLOR";
    private readonly string _shaderKeywordGreen = "FORCE_GREEN_COLOR";
    private readonly string _shaderKeywordBlue = "FORCE_BLUE_COLOR";

    /// <summary>
    /// 全てのキーワードを無効化する
    /// </summary>
    [ContextMenu("ResetShaderKeyword")]
    public void ResetShaderKeyword()
    {
        // シェーダのキーワードの定義を削除する
        Shader.DisableKeyword(_shaderKeywordRed);
        Shader.DisableKeyword(_shaderKeywordGreen);
        Shader.DisableKeyword(_shaderKeywordBlue);
    }
    
    /// <summary>
    /// 赤色にするキーワードと緑色にするキーワードを組み合わせる
    /// </summary>
    [ContextMenu("SetShaderKeywordYellow")]
    public void SetShaderKeywordYellow()
    {
        // シェーダのキーワードの定義を追加する
        Shader.EnableKeyword(_shaderKeywordRed);
        Shader.EnableKeyword(_shaderKeywordGreen);
        
        // シェーダのキーワードの定義を削除する
        Shader.DisableKeyword(_shaderKeywordBlue);
    }

    /// <summary>
    /// 強制的に赤色にするキーワードを有効化する
    /// </summary>
    [ContextMenu("SetShaderKeywordRed")]
    public void SetShaderKeywordRed()
    {
        // シェーダのキーワードの定義を追加する
        Shader.EnableKeyword(_shaderKeywordRed);
        
        // シェーダのキーワードの定義を削除する
        Shader.DisableKeyword(_shaderKeywordGreen);
        Shader.DisableKeyword(_shaderKeywordBlue);
    }
    
    /// <summary>
    /// 強制的に緑色にするキーワードを有効化する
    /// </summary>
    [ContextMenu("SetShaderKeywordGreen")]
    public void SetShaderKeywordGreen()
    {
        // シェーダのキーワードの定義を追加する
        Shader.EnableKeyword(_shaderKeywordGreen);
        
        // シェーダのキーワードの定義を削除する
        Shader.DisableKeyword(_shaderKeywordRed);
        Shader.DisableKeyword(_shaderKeywordBlue);
    }
    
    /// <summary>
    /// 強制的に青色にするキーワードを有効化する
    /// </summary>
    [ContextMenu("SetShaderKeywordBlue")]
    public void SetShaderKeywordBlue()
    {
        // シェーダのキーワードの定義を追加する
        Shader.EnableKeyword(_shaderKeywordBlue);
        
        // シェーダのキーワードの定義を削除する
        Shader.DisableKeyword(_shaderKeywordRed);
        Shader.DisableKeyword(_shaderKeywordGreen);
    }
    
#if UNITY_EDITOR
    private void OnApplicationQuit()
    {
        ResetShaderKeyword();
    }
#endif
}

シェーダで赤、緑、青の発色の組み合わせが成功するケースと失敗するケースのキーワード定義を試してみます。

組み合わせ可能なケース

以下の通り、multi_compile の定義を複数行で記述したシェーダで動作確認します。
・UnlitCombineKeywordShader.shader

Shader "Unlit/UnlitCombineKeywordShader"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog

            // multi_compileで動的に切り替えるキーワードを定義
            // 条件を組み合わせて利用したい場合は別々に定義する必要がある
            #pragma multi_compile _ FORCE_RED_COLOR
            #pragma multi_compile _ FORCE_GREEN_COLOR
            #pragma multi_compile _ FORCE_BLUE_COLOR
            
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                UNITY_TRANSFER_FOG(o,o.vertex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);
                // apply fog
                UNITY_APPLY_FOG(i.fogCoord, col);

#if defined(FORCE_RED_COLOR) || defined(FORCE_GREEN_COLOR) || defined(FORCE_BLUE_COLOR)
                col = float4(0, 0, 0, 1);
#endif
                
#if defined(FORCE_RED_COLOR)
                // FORCE_RED_COLORが定義されていれば赤色成分を強制的に1にする
                col.r = 1;
#endif
                
#if defined(FORCE_GREEN_COLOR)
                // FORCE_GREEN_COLORが定義されていれば緑色成分を強制的に1にする
                col.g = 1;
#endif
                
#if defined(FORCE_BLUE_COLOR)
                // FORCE_BLUE_COLORが定義されていれば青色成分を強制的に1にする
                col.b = 1;
#endif

                return col;
            }
            ENDCG
        }
    }
}

このシェーダに対して赤色と緑色のキーワードを組み合わせる SetShaderKeywordYellow メソッドを実行してみます。
以下の通り、どちらのキーワードの処理も実行されて色が混ざり発色が黄色になりました。

組み合わせ不可能なケース

次に、multi_compile の定義を一行で記述したシェーダで動作確認します。
・UnlitMultiKeywordShader.shader

Shader "Unlit/UnlitMultiKeywordShader"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog

            // multi_compileで動的に切り替えるキーワードを定義
            // _ (何も定義されていない状態), FORCE_RED_COLOR, FORCE_GREEN_COLOR, FORCE_BLUE_COLOR
            #pragma multi_compile _ FORCE_RED_COLOR FORCE_GREEN_COLOR FORCE_BLUE_COLOR
            
            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                UNITY_TRANSFER_FOG(o,o.vertex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);
                // apply fog
                UNITY_APPLY_FOG(i.fogCoord, col);

#if defined(FORCE_RED_COLOR) || defined(FORCE_GREEN_COLOR) || defined(FORCE_BLUE_COLOR)
                col = float4(0, 0, 0, 1);
#endif
              
#if defined(FORCE_RED_COLOR)
                // FORCE_RED_COLORが定義されていれば赤色成分を強制的に1にする
                col.r = 1;
#endif
                
#if defined(FORCE_GREEN_COLOR)
                // FORCE_GREEN_COLORが定義されていれば緑色成分を強制的に1にする
                col.g = 1;
#endif
                
#if defined(FORCE_BLUE_COLOR)
                // FORCE_BLUE_COLORが定義されていれば青色成分を強制的に1にする
                col.b = 1;
#endif

                return col;
            }
            ENDCG
        }
    }
}

このシェーダに対して赤色と緑色のキーワードを組み合わせる SetShaderKeywordYellow メソッドを実行してみます。
すると、こちらはどれか１つのキーワードを有効にしたパターンしか実行できないため、赤色に発色しました。

このようにシェーダで複数のキーワードを組み合わせて動作を定義したい場合は multi_compile の定義の仕方に注意してください。
一方で multi_compile を複数行に分け過ぎると生成されるバリアントの総数が乗算で増えていく点にも注意が必要です。