Unityでスクリプトからシェーダのキーワード定義を変更して処理を切り替える

本日はUnityの小ネタ枠です。
Unityでスクリプトからシェーダのキーワード定義を変更して処理を切り替える方法です。

シェーダバリアント

シェーダーバリアントはシェーダーコードに条件付き動作を導入する方法の 1 つです
シェーダー内にキーワードを定義するとキーワード毎に分岐した処理を記述でき、内部的には分岐毎に異なるシェーダファイル(バリアント)が作られます。
docs.unity3d.com

shader_featureまたはmulti_compileを使ってキーワードを定義します。
shader_featureは実際に利用されているバリアントのみ作成され、multi_compileは全てのバリアントを作成します。
このため、キーワードを動的に切り替えたい場合はmulti_compileを利用します。

// multi_compileで動的に切り替えるキーワードを定義
// _ (何も定義されていない状態), FORCE_RED_COLOR, FORCE_GREEN_COLOR
#pragma multi_compile _ FORCE_RED_COLOR FORCE_GREEN_COLOR

スクリプトからシェーダのキーワードを切り替えるにはShader.EnableKeywordまたはShader.DisableKeywordを利用します。
docs.unity3d.com
docs.unity3d.com

マテリアルごとに切り替えたい場合はMaterial.EnableKeywordまたはMaterial.DisableKeywordを利用します。
docs.unity3d.com
docs.unity3d.com

サンプルスクリプト

以下の通常のカラーまたは赤色、緑色の発色をキーワードで切り替えるUnlitシェーダを作成しました。
処理の分岐のほかにmulti_compileで切り替えるキーワードの定義が必要である点に注意してください。
・UnlitKeywordShader.shader

Shader "Unlit/UnlitKeywordShader"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog

            // multi_compileで動的に切り替えるキーワードを定義
            // _ (何も定義されていない状態), FORCE_RED_COLOR, FORCE_GREEN_COLOR
            #pragma multi_compile _ FORCE_RED_COLOR FORCE_GREEN_COLOR

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                UNITY_TRANSFER_FOG(o,o.vertex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);
                // apply fog
                UNITY_APPLY_FOG(i.fogCoord, col);
                
#if defined(FORCE_RED_COLOR)
                // FORCE_RED_COLORが定義されていれば強制的に赤色にする
                col = float4(1, 0, 0, 1);
#elif defined(FORCE_GREEN_COLOR)
                // FORCE_GREEN_COLORが定義されていれば強制的に緑色にする
                col = float4(0, 1, 0, 1);
#endif

                return col;
            }
            ENDCG
        }
    }
}

スクリプトからキーワードを切り替える以下のサンプルスクリプトを作成しました。
・ShaderController.cs

using UnityEngine;

public class ShaderController : MonoBehaviour
{
    private readonly string _shaderKeywordRed = "FORCE_RED_COLOR";
    private readonly string _shaderKeywordGreen = "FORCE_GREEN_COLOR";

    /// <summary>
    /// 全てのキーワードを無効化する
    /// </summary>
    [ContextMenu("ResetShaderKeyword")]
    public void ResetShaderKeyword()
    {
        // シェーダのキーワードの定義を削除する
        Shader.DisableKeyword(_shaderKeywordRed);
        Shader.DisableKeyword(_shaderKeywordGreen);
    }
    
    /// <summary>
    /// 強制的に赤色にするキーワードを有効化する
    /// </summary>
    [ContextMenu("SetShaderKeywordRed")]
    public void SetShaderKeywordRed()
    {
        // シェーダのキーワードの定義を追加する
        Shader.EnableKeyword(_shaderKeywordRed);
        
        // シェーダのキーワードの定義を削除する
        Shader.DisableKeyword(_shaderKeywordGreen);
    }
    
    /// <summary>
    /// 強制的に緑色にするキーワードを有効化する
    /// </summary>
    [ContextMenu("SetShaderKeywordGreen")]
    public void SetShaderKeywordGreen()
    {
        // シェーダのキーワードの定義を追加する
        Shader.EnableKeyword(_shaderKeywordGreen);
        
        // シェーダのキーワードの定義を削除する
        Shader.DisableKeyword(_shaderKeywordRed);
    }
    
#if UNITY_EDITOR
    private void OnApplicationQuit()
    {
        ResetShaderKeyword();
    }
#endif
}