UnityのHLSLシェーダで時間経過で明滅するシェーダを作成する

本日はUnityの小ネタ枠です。
UnityのHLSLシェーダで時間経過で明滅するシェーダを作成する方法です。

シェーダーの時間変数

ビルトインのシェーダー変数の _Time を参照することでステージロードからの時間(t/20, t, t*2, t*3)をシェーダ内で参照できます。
本変数を使ってシェーダ内で時間経過に応じたアニメーションを実装することができます。
docs.unity3d.com

時間変数には以下の4種類が用意されています。

名前	タイプ	Value
_Time	float4	ステージのロードからの時間 (t/20, t, t2, t3)
_SinTime	float4	時間の正弦: (t/8, t/4, t/2, t)
_CosTime	float4	時間の余弦: (t/8, t/4, t/2, t)
unity _DeltaTime	float4	デルタ時間: (dt, 1/dt, smoothDt, 1/smoothDt)

サンプルシェーダ

_Time変数を使って一定時間ごとに指定された色に変化して点滅する以下のUnlitシェーダを作成しました。
・FlickerUnlitShader.shader

Shader "Unlit/FlickerUnlitShader"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
        
        // <------- ここからが点滅処理の追加部分 ------->
        // 点滅の色
        _FlickerColor ("Flicker Color", Color) = (1,1,1,1)
        
        // 点滅の時間間隔(1に設定すると1秒で1回点滅)
        _FlickerInterval ("Flicker Interval", Range(0.1, 10)) = 1
        // <------- ここまで点滅処理の追加部分 ------->
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 100

        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                UNITY_FOG_COORDS(1)
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                UNITY_TRANSFER_FOG(o,o.vertex);
                return o;
            }

            // <------- ここからが点滅処理の追加部分 ------->
            fixed4 _FlickerColor;
            float _FlickerInterval;
            // <------- ここまで点滅処理の追加部分 ------->

            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);
                // apply fog
                UNITY_APPLY_FOG(i.fogCoord, col);

                // <------- ここからが点滅処理の追加部分 ------->
                // 点滅間隔で時間を割って0~1の範囲に収める
                float flickerTime = fmod(_Time.y, _FlickerInterval) / _FlickerInterval;
                // 連続的に点滅させるため0~1~0の範囲で値を変動させる
                float interpolatedValue = (flickerTime < 0.5) ? flickerTime * 2 : 1 - (flickerTime - 0.5) * 2;
                // 通常色~点滅色をLerpでスムーズに遷移させる
                col = lerp(col, _FlickerColor, interpolatedValue);
                // <------- ここまで点滅処理の追加部分 ------->
                
                return col;
            }
            ENDCG
        }
    }
}